{************************************
*                                   *
*  This file provides a             *
*  FRP /encoder/ functions for      *
*  _211-06/12 Extended Counter      *
*                                   *
*  16 - Mar - 2007`                 *
*  PIC18F2620 @ 40 MHz              *
*  MikroPascal v6.0.0.2             *
*                                   *
*  rsrachev@gmail.com               *
*                                   *
************************************}
unit frp_211;

uses definitions_211, counters_file;

const
  FRP_ENABLE         : byte = 0;
  FRP_ENABLED        : byte = 1;
  FRP_DISABLED       : byte = 0;
  //FRP_ONLINE         : byte = 1;
  //FRP_OFFLINE        : byte = 0;
 
var
  frp_input_A_now, frp_input_A_pre, frp_input_A      : word;  // TIMER3
  frp_input_B_now, frp_input_B_pre, frp_input_B      : word;  // TIMER0
  frp_UP, frp_DOWN                                   : word;  // |A - B|
  in_A_L, in_A_H, in_B_L, in_B_H                     : byte;
  input_divider_UP_counter, input_divider_DOWN_counter               : word;
  FRP_MODULE_ENABLED                                 : byte; register;

implementation

procedure FRP_Init(var frp_port : byte; frp_pin : byte; frp_online : boolean);
var
  ddr_port : ^byte;  //a pointer to TRIS REG
begin
  ddr_port := @frp_port + TRIS_OFFSET;  //Get TRIS address
  ddr_port^.frp_pin := 0;
  if frp_online then
    begin
      //TMR0H := 0; TMR0L := 0;
      //TMR3H := 0; TMR3L := 0;
      frp_input_A_pre := 0;
      frp_input_B_pre := 0;
      input_divider_UP_counter := 1;
      input_divider_DOWN_counter := 1;
      CCP1CON := 0;
      CCPR1H := 0; CCPR1L := 0;
      T0CON := %10101000;
      T3CON := %10000011;  //16 bit mode with sync input!!!
      frp_port.frp_pin := FRP_ENABLED;
      FRP_MODULE_ENABLED := True;
      TMR0H := 0; TMR0L := 0;  //moved here to solve bug 'count at startup'
      TMR3H := 0; TMR3L := 0;
    end
  else
    begin
      T0CON.TMR0ON := 0;
      T3CON.TMR3ON := 0;
      frp_port.frp_pin := FRP_DISABLED;
      FRP_MODULE_ENABLED := False;
     
      ddr_port^.frp_pin := 1;
    end;
end;

procedure FRP_Handle;
begin
  if direction_1_value = _FORWARD then  //change count direction
    begin
      in_A_L := TMR3L; in_A_H := TMR3H;
      in_B_L := TMR0L; in_B_H := TMR0H;
    end
  else
    begin
      in_A_L := TMR0L; in_A_H := TMR0H;
      in_B_L := TMR3L; in_B_H := TMR3H;
    end;
 
  frp_input_A_now := 0;
  frp_input_A_now := (in_A_H shl 8) + in_A_L;

  frp_input_B_now := 0;
  frp_input_B_now := (in_B_H shl 8) + in_B_L;


  frp_UP := frp_input_A_now - frp_input_A_pre;

  frp_DOWN := frp_input_B_now - frp_input_B_pre;


  frp_input_A_pre := frp_input_A_now;
  frp_input_B_pre := frp_input_B_now;
  if frp_DOWN > frp_UP then
    direction_1 := BACKWARD;
  if frp_DOWN < frp_UP then
    direction_1 := _FORWARD;

  while (frp_DOWN >= 1) do
    begin
      Inc(input_divider_DOWN_counter);
      input_divider_UP_counter := input_divider_1_value - input_divider_DOWN_counter + 1;
      if input_divider_DOWN_counter > input_divider_1_value then
        begin
          input_divider_UP_counter := 1;
          input_divider_DOWN_counter := 1;
          if prescaler_1_in_use then
            Multiply_Counter_1_On_Dec
          else
            Dec_Counter_1;
        end;
      Dec(frp_DOWN);
    end;

  while (frp_UP >= 1) do
    begin
      Inc(input_divider_UP_counter);
      input_divider_DOWN_counter := input_divider_1_value - input_divider_UP_counter + 1;
      if input_divider_UP_counter > input_divider_1_value then
        begin
          input_divider_UP_counter := 1;
          input_divider_DOWN_counter := 1;
          if prescaler_1_in_use then
            Multiply_Counter_1
          else
            Inc_Counter_1;
        end;
      Dec(frp_UP);
    end;

end;

procedure FRP_Set;
begin
  if MAIN_TASK_Dispatcher = ENCODER_MODE then
    FRP_Init(PORTA, FRP_ENABLE, True)
  else
    FRP_Init(PORTA, FRP_ENABLE, False);
end;

end.